Personal Computer World 2005 October/PCWOCT05.iso/Software/FromTheMag/Ant Movie Catalog 3.5.0.2/amc_install.exe/{app}/Scripts/Monsieur Cinéma.ifs

Text File | 2005-04-12 | 30KB | 704 lines

(***************************************************

Ant Movie Catalog importation script
www.antp.be/software/moviecatalog/

[Infos]
Authors=scorpion7552 (scripts originaux: Antoine Potten (MrCinΘma) et Danone-Kid (CinΘfil))
Title=Monsieur CinΘma
Description=infos de MrCinΘma - mode normal/batch: voir l'onglet Commentaires
Site=http://cinema.tiscali.fr
Language=FR
Version=5.2
Requires=3.5.0
Comments=mode batch: 2 modes possibles: d'aprΦs l'url mΘmorisΘe (MrCinΘma) ou d'aprΦs le nom du film + rΘalisateur (rΘsultats non garantis!)|N'oubliez pas de sauvegarder votre base actuelle avant de lancer le mode batch|Conseils: sΘlectionnez un nombre raisonnable de films et triez la liste des films par numΘros|α la fin de chaque mise α jour, un fichier log est crΘΘ (informations et erreurs - attention ce fichier est recrΘΘ α chaque lancement de ce script)
License=This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version.
GetInfo=1

[Options]
Image=1|1|0=aucune image|1=image MrCinΘma seule|2=image CinΘfil seule|3=toutes les images
Histoire=0|0|0=rΘsumΘ (s'il existe, sinon histoire complΦte)|1=histoire complΦte
Anecdote=0|0|0=pas d'anecdote|1=anecdote α la suite de l'avis de la rΘdaction (Commentaires)
GΘnΘrique=0|0|0=gΘnΘrique rΘduit|1=gΘnΘrique complet
FormatTitre=0|0|0=laisser les titres des films tels quels|1=tout en minuscules|2=tout en majuscules|3=1Φre lettre en majuscule le reste en minuscules|4=toutes les 1Φres lettres en majuscules
Mode=0|0|0=mode normal|1=mode batch (url)|2=mode batch (nom + rΘalisateur)

***************************************************)

// nΘcessite les modules suivants
// StringUtils1.pas, StringUtils7552.pas et MrCinemaCinefilCommon.pas

program MonsieurCinema;
uses
    MrCinemaCinefilCommon;

const
    MrCinemaUrl = 'http://cinema.tiscali.fr/';
    MrCinemaUrlFilm = MrCinemaUrl + 'fichefilm.aspx';
{ recherche: films classΘs par titres (on peut aussi faire &filtre=annee)}
    MrCinemaUrlLook = MrCinemaUrl + 'recherche.aspx?file=http&filtre=titre&keys=';

var
     viewstate, idhistoire, idavis, idgenerique, idanecdote, annee: string;
    ImportPicture: integer;

//------------------------------------------------------------------------------
// recherche du film
// MovieName = nom du film cherchΘ (tel que saisi, cad non formatΘ)
//------------------------------------------------------------------------------
procedure AnalyzePageMrCinema;
var
    Address, Page, Value, PageFilm, urlFilm: String;
    pagenum, i: integer;
    memo: TStringList;

begin
    pagenum := 0;                                             // compteur de pages
// init adresse 1Φre recherche
    Address := MrCinemaUrlLook+FormatMovieName2(MovieName);
    repeat
    PageNext := '';
    PagePrev := '';
// traitement page courante
// attention aux positionnements: les textes sont au format UTF-8
    pagenum := pagenum + 1;
    FormatUTF8 := 1;
    memoAdr := TStringList.Create;                          // init listes de mΘmo
    memoTxt := TStringList.Create;
    Page := GetPage(UrlEncode(Address));
    if debug then
        DumpPage(debugrep+'choixMrCinema'+IntToStr(pagenum)+'.txt', Page);    // debug
    Page := TextAfter(Page, 'Vous effectuez une recherche sur');
    if Page = '' then
    begin
        LogMessage('MrCinΘma: erreur lecture page de recherche '+IntToStr(pagenum));
        memoAdr.Free;
        memoTxt.Free;
        exit;
    end;
// c'est ici qu'il faudrait mΘmoriser PagePrev/PageNext
// pour l'instant il n'y en pas, mais c'est pas une raison pour ne pas le prΘvoir ...
    if PagePrev <> '' then
    begin
        memoAdr.Add(PagePrev);
        memoTxt.Add('<<< page prΘcΘdente');
    end;
// mΘmo des films de cette page (if any)
    urlFilm := '<a href="' + MrCinemaUrlFilm+'?id=';
    memo := TStringList.Create;
    memo.Text := StringReplace(Page, '<br>', crlf);  // sΘpare lignes
    for i := 0 to memo.Count-1 do
    begin
        Value := memo.GetString(i);
        PageFilm := GetUrl(Value, urlFilm, '');        // inclut &file=http
        if PageFilm = '' then continue;                // pas d'url: ligne vide
// 5.1: il y a maintenant une distinction entre films et DVD
// fiche 'DVD' = fiche film + infos DVD supplΘmentaires
// comme il n'y a plus de place pour ranger ces infos, autant ignorer ces entrΘes
        if Pos('type=dvd', AnsiLowerCase(PageFilm)) > 0 then continue;
        memoAdr.Add(PageFilm);
// Value = nom du film, de rΘalisateur (annΘe) rq: (annΘe) facultative
// sΘparer 'nom du film' et 'rΘalisateur (annΘe)' avant HTMLRemoveTags
        Value := StringReplace(Value, '</a>', sepchar1);  // aprΦs le titre
        memoTxt.Add(FormatText(Value));
    end;         {for i}
    memo.Free;
     if PageNext <> '' then
    begin
        memoAdr.Add(PageNext);
        memoTxt.Add('>>> page suivante');
    end;
    if memoAdr.Count = 0 then
    begin
        LogMessage('MrCinΘma: aucun film trouvΘ pour "'+MovieName+'"');
        memoAdr.Free;
        memoTxt.Free;
        exit;
    end;
    if BatchMode > 0 then
    begin
// mode batch : recherche du meilleur poids pour les films de cette page
        LookBest(mrcinema_id);
        if (bestpoids = maxcount) or (PageNext = '') or (pagenum > pagemax) then
// poids max ou pas de page next ou max pages lues: on arrete
        begin
            if bestpoids > 0 then                         // on a trouvΘ quelque chose
            begin
                if bestpoids < maxcount then                         // infos partielles
                        LogMessage('MrCinΘma: '+looktxt+' retenu '+besttxt+' (poids='+IntToStr(bestpoids)+')');
                AnalyzeMoviePageMrCinema(bestadr);                          // page film
            end else
                LogMessage('MrCinΘma: pas de correspondance pour '+looktxt);
            break;               // on sort
        end else
// sinon, on va chercher s'il y a mieux mieux dans pagenext
        Address := PageNext;
    end else
// mode normal
    begin
        Address := SelectMovie('Films (Monsieur CinΘma)');
        if Address <> '' then
        begin
            if (Address <> PageNext) and (Address <> PagePrev) then
            begin
                AnalyzeMoviePageMrCinema(Address);                          // page film
                break;                                                      // on sort
            end;
        end else
            LogMessage('MrCinΘma: aucun film sΘlectionnΘ');
    end;
    until (Address = '');
    memoAdr.Free;
    memoTxt.Free;
end;

//------------------------------------------------------------------------------
// analyse de la page du film
//------------------------------------------------------------------------------
procedure AnalyzeMoviePageMrCinema(Address: string);

var
    Fullpage, PageEssentiel, PageHistoire, PageAvis, PageGenerique, PageAnecdote: string;
    Value, Value2, titreo, titret, realisateur, producteur, duree, acteurs: string;
    memo: TStringList;
    i: integer;

begin
// attention aux positionnements: les textes sont au format UTF-8
    FormatUTF8 := 1;
    annee := '';
    Fullpage := GetPage(Address);          // charge la 1Φre page ("l'essentiel")
    if debug then
        DumpPage(debugrep+'filmMrCinema.txt', Fullpage);    // debug
    if Pos('<b>L''essentiel</b>', Fullpage) = 0 then
    Begin
        LogMessage('MrCinΘma: erreur lecture page essentiel');
        exit;
    end;
    filmok := True;                                         // τa y est, c'est bon
    SetField(fieldURL, Address);
    GetSubParms(Fullpage);      // rΘcupΦre les identifiants des pages secondaires
// infos utiles de la page "essentiel"
    PageEssentiel := TextBetween(Fullpage, '<!-- Contenu des onglets -->', '</form>');
//********** gΘnΘrique
//*** les infos du gΘnΘrique sont plus ou moins valorisΘes
//*** quant α l'annΘe, elle peut Ωtre vraiment n'importe o∙ !!!
// si gΘnΘrique complet demandΘ
    if (GetOption('GΘnΘrique') = 1) and (idgenerique <> '') then
    begin
        PageGenerique := GetSubPage(Address, idgenerique, 'generique');
// titre Original/traduit
        titret := TextBetween(PageGenerique, '<b class="sous_titre">', '</b>');
        titreo := TextBetween(PageGenerique, '<span class="sous_titre">', '</span>');
// sΘparer les 2 tables
        Value := TextBetween(PageGenerique, '<TABLE WIDTH=100%>', '</TABLE>');      // infos gΘnΘrales
        acteurs := TextBetween(RemainingText, '<TABLE WIDTH=100%>', '</TABLE>');    // r⌠les/acteurs
// acteurs
        acteurs := FormatTable(acteurs, 'nocont');     // ne pas recoller les lignes
        acteurs := StringReplace(acteurs, sepchar2, '-');
// infos gΘnΘrales
        Value := FormatTable(Value, '');               // recoller les lignes
// rΘalisateur (et annΘe)
        realisateur := ExtractInfo(Value, 'r├⌐alis');   // rΘalisation, rΘalisateur, rΘalisΘ,...
        ExtrAnnee(realisateur);
// producteur (parfois c'est "rΘalisΘ et produit par machin (annΘe)" )
        producteur := ExtractInfo(Value, 'produ');     // produit, production, ...
        ExtrAnnee(producteur);
// durΘe
        duree := ExtractInfo(Value, 'dur├⌐e');         // durΘe
        duree := FormatText(TextBefore(duree, 'minutes', ''));
    end;
// si pas de gΘnΘrique complet ou champs non trouvΘs, on essaie dans la page 'essentiel'
// titre original
    if titret = '' then
        titret := TextBetween(PageEssentiel, '<b class="sous_titre">', '</b>');
// titre traduit (et annΘe)
    Value := TextBetween(PageEssentiel, '<span class="sous_titre">', '</span>');
    ExtrAnnee(Value);                           // 5.1: l'annΘe est maintenant ici
    if titreo = '' then
        titreo := Value;
// rΘalisateur
    Value := TextAfter(PageEssentiel, '<br>');
    if realisateur = '' then
        realisateur := TextBetween(Value, 'de', '</a>');
// annΘe (anciennes fiches)
    if annee = '' then
    begin
        annee := TextBetween(Value, '</a>', 'avec');
        annee := TextBetween(annee, '(', ')');
    end;
// acteurs
    if acteurs = '' then
    begin
        acteurs := TextBetween(Value, 'avec', '<div');
        acteurs := StringReplace(acteurs, ', ...', '');   // je ne sais pas si τa existe encore
    end;
// (pas d'info 'producteur' dans la page 'essentiel')
//********** mise α jour des champs du gΘnΘrique
// titre original et traduit
    titret := FormatText(titret);                     // titre traduit ou original
    titreo := StringReplace(titreo, '(', '');
    titreo := StringReplace(titreo, ')', '');
    titreo := FormatText(titreo);                     // original ou ''
    titret := TranslateText(titret, FormatTitre);
    titreo := TranslateText(titreo, FormatTitre);
    if (titreo = '') or (titreo = titret) then             // 1er titre = original
    begin
        SetField(fieldOriginalTitle, titret);
        SetField(fieldTranslatedTitle, '');
    end else
    begin                                                  // traduit + original
        SetField(fieldOriginalTitle, titreo);
        SetField(fieldTranslatedTitle, titret);
    end;
    SetField(fieldDirector, FormatText(realisateur));      // rΘalisateur
    SetField(fieldYear, FormatText(annee));                // annΘe
    SetField(fieldProducer, FormatText(producteur));       // producteur
    SetField(fieldActors, FormatText(acteurs));            // acteurs
// durΘe: SetField fait plus tard
//********** Description (rΘsumΘ ou histoire complΦte)
    Value := TextBetween(PageEssentiel, '<div align="justify">', '</div>');     // rΘsumΘ
    if (idhistoire <> '') and ((Value = '') or (GetOption('Histoire') = 1) or (Pos('>Lire la suite<', Value) > 0)) then
    begin    // 5.1 pas de rΘsumΘ ou dΘbut de histoire complΦte ou histoire complΦte demandΘe
        PageHistoire := GetSubPage(Address, idhistoire, 'histoire');
        Value := TextBetween(PageHistoire, '<div align="justify">', '</div>');
    end;
    SetField(fieldDescription, FormatText(Value));
//********** avis de la rΘdaction, note (peuvent Ωtre dans la page "essentiel") + anecdote
    Value := '';
    PageAvis := TextAfter(Fullpage, '<b>L''avis de la rédaction</b>' );
    if (PageAvis = '') and (idavis <> '') then                        // avis sur autre page
        PageAvis := GetSubPage(Address, idavis, 'avis');
    Value := FormatText(TextBetween(PageAvis, '<div align="justify"><p>', '</div>'));
// Value = avis de la rΘdaction: garder pour complΘter avec l'anecdote
    Value2 := TextBetween(PageAvis, '<img src="img/', 'redac.gif"');   // note 0 α 9 ou ''
    if (Pos('<b>Aucun avis de la redaction.</b>', PageAvis) > 0) and (Value2 = '0') then
        Value2 := '';                         // pas d'avis et img = 0redac.gif alors ignorer
    if Value2 <> '' then
        Value2 := IntToStr(StrToInt(Value2, 0) * 2);                   // note = 2 * x
    SetField(fieldRating, Value2);
// on ajoute l'anecdote si demandΘ et existant
    if (GetOption('Anecdote') = 1) and (idanecdote <> '') then
    begin
        PageAnecdote := GetSubPage(Address, idanecdote, 'anecdote');
        Value2 := FormatText(TextBetween(PageAnecdote, '<div align="justify">', '</div>'));
        if Value2 <> '' then
        begin
            if Value <> '' then Value := Value + crlf + crlf;
            Value := Value + 'Anecdote' + crlf + Value2;
        end;
    end;
    SetField(fieldComments, Value);
//********** hors zone dynamique
// 5.2 changement de certains tags
    Value2 := TextBetween(Fullpage, '<table cellpadding="0" cellspacing="0" border="0" class="boite_arrondie" style="background-color: #e5e5e5; special;" width="423" height="180">', '</table>');
// genre
    Value := FormatText(TextBetween(Value2, '<b>Genre</b></div>', '</div>'));
    SetField(fieldCategory, Value);
// durΘe (sauf si dΘjα fait)
    if duree = '' then
    begin                    // format hh:mm:ss α transformer en minutes
        duree := FormatText(TextBetween(Value2, '<b>Durée</b></div>', '</div>'));
        if duree <> '' then              // format hh:mm:ss
            duree := IntToStr(StrToInt(Left(duree, 2), 0) * 60 + StrToInt(Copy(duree, 4, 2), 0));
    end;
    SetField(fieldLength, duree);                           // on range maintenant
// pays
    Value := FormatText(TextBetween(Value2, '<b>Pays </b></div>', '</span>'));
    if Value <> '' then
    begin                       // pas toujours trΦs cohΘrents les noms de pays...
        Value := StringReplace(Value, '.', '');
        Value := StringReplace(Value, ',', '');
        Value := StringReplace(Value, '/', ' ');
        Value := StringReplace(Value, '-' ,' ');
        Value := CompactString(Value, '');
        Value := TranslateText(Value, 4);
        Value := StringReplace(Value, 'Usa', 'Etats-Unis');
        Value := StringReplace(Value, 'Etats Unis', 'Etats-Unis');
        Value := StringReplace(Value, 'Grande Bretagne', 'Grande-Bretagne');
        Value := StringReplace(Value, 'Nouvelle ZΘlande', 'Nouvelle-ZΘlande');
// tri
        memo := TStringList.Create;
        memo.Text := StringReplace(Value, ' ', crlf);
        SortList(memo);
        Value := Trim(StringReplace(memo.Text, crlf, ' '));
        memo.Free;
    end;
    SetField(fieldCountry, Value);
//********** image si demandΘe (rappel: ImportPicture = 0 si not CanSetPicture)
    if (ImportPicture = 1) or (ImportPicture = 3) then
    begin
        Value := TextBetween(Value2, '<img src="', '"');
        if Value <> '' then GetPicture(Value);
    end;
end;

//------------------------------------------------------------------------------
// extraction de l'annΘe dans une chaine (texte_α_garder (annΘe) )
//------------------------------------------------------------------------------
procedure ExtrAnnee(var str: string);
var
    i: integer;

begin
    i := LastPos('(1', str);              // (1xxx ou (2xxx τa devrait suffire !!!
    if i = 0 then
        i := LastPos('(2', str);
    if i > 0 then                                  // annΘe trouvΘe
    begin
        if annee = '' then
            annee := Copy(str, i+1, 4);
        str := Left(str, i -1);                      // chaine initiale sans l'annΘe
    end;
end;

//------------------------------------------------------------------------------
// formatage du nom du film
//------------------------------------------------------------------------------
function FormatMovieName2(str: string) :string;
var
    i, j: integer;

begin
// une petite Θdition avant de formater
    str := StringReplace(str, ' & ', ' et ');
    str := StringReplace(str, ' & ', ' et ');
// MrCinΘma traite bizarrement SES titres s'ils contiennent une virgule ou deux points
// exemple "2001 l'odyssΘe de l'espace" connu sous "2001 : l'odyssΘe de l'espace"
// il faut rentrer soit "2001" , soit "l'odyssee de l'espace"
// mais pas les 2 (il ne rend rien dans ce cas: oui, c'est bien bizarre...)
// donc on s'arrΩte aussi au premier de ces caractΦres (mais τa rΦgle pas tout)
    i := Pos(',', str);
    j := Pos(':', str);
    if (i <> 0) or (j <> 0) then           // au moins 1 de trouvΘ
    begin
        if i = 0 then
            i := j
        else
        begin
            if (j <> 0) and (i > j) then i := j;
        end;
        str := Left(str, i -1);
    end;
    result := FormatMovieName(str);
end;

//------------------------------------------------------------------------------
// formatage d'une table (gΘnΘrique)
//------------------------------------------------------------------------------
function FormatTable(str1, flag: string) :string;
var
    sepcel: string;

begin
// structure table
// <TR ...>                      = dΘbut de ligne
//   <TD ...> texte </TD>        = 1 cellule
//   ....................          autres cellules
// </TR>                         = fin de ligne
    str1 := StringReplace(str1, crlf, '');              // supprimer les crlf
    str1 := StringReplace(str1, '<TR', crlf+'<');       // dΘbut de ligne = crlf
    str1 := StringReplace(str1, '<TD>', sepchar2);      // cellule du 'milieu'
    str1 := StringReplace(str1, '<TD ', sepchar1+'<');  // 1Φre cellule
    HTMLRemoveTags(str1);                               // supprimer les autres tags
    str1 := StringReplace(str1, sepchar1+crlf, '');     // supprimer les lignes vides
// dΘterminer le 1er sΘparateur de cellule (plusieurs sortes de coding...)
// crlf+sepchar1          = <TD ...>texte
// crlf+sepchar1+sepchar2 = <TR><TD ...></TD><TD>texte
// et le remplacer par crlf (α priori seuls cas possibles)
    sepcel := crlf+sepchar1+sepchar2;
    if Pos(sepcel, str1) <> 1 then sepcel := crlf+sepchar1;
    str1 := StringReplace(str1, sepcel, crlf);
// s'il reste des crlf+sepchar2+sepchar2 ou crlf+sepchar2, il s'agit de continuations de lignes
// recoller les lignes si demandΘ
    if flag = 'nocont' then
        sepcel := crlf                   // on recolle pas
    else
        sepcel := ' ';                   // 1 blanc pour ne pas coller au prΘcΘdent
    str1 := StringReplace(str1, crlf+sepchar2+sepchar2, sepcel);
    str1 := StringReplace(str1, crlf+sepchar2, sepcel);
//
    str1 := StringReplace(str1, sepchar2+sepchar2, sepchar2);        // supprimer les cellules vides
    str1 := StringReplace(str1, sepchar2+sepchar2, sepchar2);        // oui, c'est voulu
    str1 := StringReplace(str1, sepchar2, ' '+sepchar2+' ');         // decoller les sΘparateurs du texte
    str1 := StringReplace(str1, sepchar1, '');                       // et celui qui reste
    result := str1;                          // suite du formatage dans FormatText
end;

//------------------------------------------------------------------------------
// extraction des infos des tables MrCinΘma
//------------------------------------------------------------------------------
Function ExtractInfo(str1, from: string) :string;
var
    i: integer;

begin
// si pas de sΘparateur de champs (sepchar2), alors on prend le mot suivant (anciennes dΘfinitions)
// d'o∙ la recherche sur des mots 'incomplets' (et en plus, τa permet de couvrir plus de cas...)
// rappel: le mot cherchΘ (from) peut contenir des majuscules
        result := '';
        i := Pos(AnsiLowerCase(from), AnsiLowerCase(str1));
        if i = 0 then exit;                                       // from non trouvΘ
        str1 := Copy(str1, i + Length(from), Length(str1));
        i := Pos(crlf, str1);
        if i > 0 then                                // si pas de crlf, prendre tout
            str1 := Left(str1, i-1);
        i := Pos(sepchar2, str1);
        if i = 0 then    i := Pos(' ', str1);
        result := Copy(str1, i +1, length(str1));
end;

//------------------------------------------------------------------------------
// rΘcupΘration des identifiants 'sous-pages'
// GetSubParms(page)
//------------------------------------------------------------------------------
procedure GetSubParms(s: string);
var
    Value: string;
    i: integer;

begin
// infos utiles
// 5.2 les url ont la bougeotte donc ne pas prΘ-dΘterminer l'ordre
    Value := TextBetween(s, '<b>L''essentiel</b>', '<!-- Contenu des onglets -->');
    if Pos('doPostBack', Value) > 0 then
    begin
// formulaire et PostPage (ancienne mΘthode)
// α garder tant que la fonction doPostBack est dΘfinie dans la page (on ne sait jamais...)
// rΘcupΦre le paramΦtre VIEWSTATE (ident de session)
        viewstate := TextBetween(s, 'name="__VIEWSTATE"', '/>');
        viewstate := TextBetween(viewstate, 'value="', '"');
// c'est un peu trop cablΘ: ordre et __EVENTARGUMENT='': serait mieux si c'Θtait plus prΘcis
// page histoire
        idhistoire := TextBetween(Value, '__doPostBack(''', '''');
        Value := RemainingText;
        if idhistoire <> '' then
        begin
            idhistoire := StringReplace(idhistoire, '$', ':');
            idhistoire := '__EVENTTARGET='+ idhistoire + '&__EVENTARGUMENT=&__VIEWSTATE=' + viewstate;
        end;
// page avis de la rΘdaction
        idavis := TextBetween(Value, '__doPostBack(''', '''');
        Value := RemainingText;
        if idavis <> '' then
        begin
            idavis := StringReplace(idavis, '$', ':');
            idavis := '__EVENTTARGET='+ idavis + '&__EVENTARGUMENT=&__VIEWSTATE=' + viewstate;
        end;
// page gΘnΘrique
        idgenerique := TextBetween(Value, '__doPostBack(''', '''');
        Value := RemainingText;
        if idgenerique <> '' then
        begin
            idgenerique := StringReplace(idgenerique, '$', ':');
            idgenerique := '__EVENTTARGET='+ idgenerique + '&__EVENTARGUMENT=&__VIEWSTATE=' + viewstate;
        end;
// page anecdote
        idanecdote := TextBetween(Value, '__doPostBack(''', '''');
        if idanecdote <> '' then
        begin
            idanecdote := StringReplace(idanecdote, '$', ':');
            idanecdote := '__EVENTTARGET='+ idanecdote + '&__EVENTARGUMENT=&__VIEWSTATE=' + viewstate;
        end;
    end
    else
    begin
// url normale (mΘthode actuelle)
// page histoire
        idhistoire := GetUrlPage(Value, '>L''histoire</a>');
// page avis de la rΘdaction
        idavis := GetUrlPage(Value,'>L''avis de la rédaction</a>');
// page gΘnΘrique
        idgenerique := GetUrlPage(Value,'>Le générique complet</a>');
// page anecdote
        idanecdote := GetUrlPage(Value,'>L''anecdote</a>');
    end;
// si certains champs ne doivent pas Ωtre valorisΘs, inutile de lire les pages supplΘmentaires
    if not CanSetField(fieldDescription) then    idhistoire := '';
    if not CanSetField(fieldComments) then idanecdote := '';
    if not CanSetField(fieldComments) and (not CanSetField(fieldRating)) then idavis := '';
// pour gΘnΘrique complet
// il faut tester 'not' pour acteurs et rΘalisateur et producteur et durΘe et annΘe
    Value := '';
    if CanSetField(fieldActors) then Value := 'ok';
    if CanSetField(fieldDirector) then Value := 'ok';
    if CanSetField(fieldProducer) then Value := 'ok';
    if CanSetField(fieldLength) then Value := 'ok';
    if CanSetField(fieldYear) then Value := 'ok';
    if Value = '' then idgenerique := '';
end;

//------------------------------------------------------------------------------
// rΘcupΘration de l'url d'une sous-page
// url := GetUrlPage(texte_contenant_l'url, texte_α_chercher)
//------------------------------------------------------------------------------
function GetUrlPage(wholetext, str: string) : string;
var
    id: string;
    i: integer;

begin
// l'url est avant le texte cherchΘ
    i := Pos(str, wholetext);
    id := left(wholetext, i + length(str));
// et aprΦs le dernier '<a '
    i := LastPos('<a ', AnsiLowerCase(id));
    result := GetUrl(Copy(id, i, length(id)), '', MrCinemaUrlFilm);
end;

//------------------------------------------------------------------------------
// rΘcupΘration des sous-pages
// pagexxx := GetSubPage(adresse_fiche_film, ident_page_cherchΘe, nom_fichier_pour_debug)
//------------------------------------------------------------------------------
function GetSubPage(Address, idpage, idfic: string) :string;
var
    page: string;

begin
    idpage := UrlEncode(idpage);
    if viewstate = '' then
// page 'normale' (getpage)
        page := GetPage(idpage)
    else
    begin
// formulaire et PostPage
// encore des caractΦres α transformer... aprΦs UrlEncode (ordre trΦs important)
        idpage := StringReplace(idpage, '+', '%2B');
        idpage := StringReplace(idpage, ':', '%3A');
        page := PostPage(Address,idpage);
    end;
    if debug then
        DumpPage(debugrep+idfic+'MrCinema.txt', page);    // debug
    if page = '' then
    Begin
        LogMessage('MrCinΘma: erreur lecture page '+idfic);
        exit;
    end;
// ne garder que la partie dynamique
    result := TextBetween(page, '<!-- Contenu des onglets -->', '</form>');
end;

//------------------------------------------------------------------------------
// traitement mode batch
//------------------------------------------------------------------------------
procedure MrCinemaBatch;
begin
    SetField(fieldChecked, '');                         // init film en traitement
    case BatchMode of
    1:
        begin
// recherche par url
            MovieName := GetField(fieldUrl);       // pas d'url ou autre site, ignorer
            if (MovieName <> '') and (Pos(MrCinemaUrlFilm, MovieName) > 0) then
                AnalyzeMoviePageMrCinema(MovieName)
            else
                LogMessage('MrCinΘma: non traitΘe url="'+Moviename+'"');
        end;
    2:
        begin
// recherche par nom    + rΘalisateur
            MovieName := GetMovieName;
            if MovieName <> '' then
            begin
                initBatchLook;                           // init paramΦtres de recherche
                AnalyzePageMrCinema;
            end else
                LogMessage('MrCinΘma: non traitΘe (pas de nom de film)');
        end;
    end;      {case}
    if filmok then
    begin
        SetField(fieldChecked, 'x');                                      // film ok
        if ((ImportPicture = 2) or (ImportPicture = 3)) then
        begin
// ok pour MrCinΘma: rechercher l'affiche CinΘfil
// (forcΘment par nom + rΘalisateur tant qu'il n'y a pas de 2Φme champ url)
            MovieName := GetMovieName;         // relecture
            if MovieName <> '' then
            begin
                initBatchLook;
                AnalyzePageCinefil;
            end;
        end;         {import picture}
    end;           {filmok}
end;

//------------------------------------------------------------------------------
// traitement mode normal
//------------------------------------------------------------------------------
procedure MrCinemaNorm;
var
    mname: string; // Input ne peut pas accΘder aux variables dΘclarΘes dans les units

begin
// Monsieur cinΘma
    mname := GetMovieName;
    msgano := 'Entrez le titre du film';
    repeat
    if not Input('MonsieurCinΘma.com Import', msgano, mname) or (mname = '') then exit;
    MovieName := mname;
    AnalyzePageMrCinema;
    until filmok;
// CinΘfil (si image demandΘe)
    if (ImportPicture = 2) or (ImportPicture = 3) then
    begin
        MovieName := GetMovieName;         // relecture
        filmok := False;
        msgano := 'Entrez le titre du film';
        repeat
        AnalyzePageCinefil;
        if not filmok then
        begin                           // page non trouvΘe ou erreur: on y retourne
            mname := MovieName;
            if not Input('CinΘfil.com Import', msgano, mname) or (mname = '') then
                exit;                                             // non saisie: on sort
            MovieName := mname;
        end;
        until filmok;
    end;      {import picture}
end;

//------------------------------------------------------------------------------
//  c'est ici que τa commence
//------------------------------------------------------------------------------
begin
    if abort = 'o' then exit;                           // mode batch non confirmΘ
    if firstcall <> 'done' then
    begin                                            // 1er appel: init paramΦtres
        firstcall := 'done';
        if not CheckVersion(3,5,0) then
        begin
            ShowMessage('Ce script requiert une version plus rΘcente de Ant Movie Catalog (au moins la version 3.5.0)');
            abort := 'o';
            exit;
        end;
        calledBy := mrcinema_id;                             // identifiant appelant
        batchlogfic := 'c:\amc_MrCinema_batchlog.txt';       // log pour mode batch
        debug := False;                       // mode debug on/off
        debugrep := 'd:\temp\';               // rΘpertoire de stockage des fichiers
// rΘcupΦre les variables user (utilisΘes plus d'une fois)
        BatchMode := GetOption('Mode');
        FormatTitre := GetOption('FormatTitre');
        ImportPicture := GetOption('Image');
        if not CanSetPicture then
            ImportPicture := 0;         // champ image non modifiable: inutile de lire
//
        if BatchMode > 0 then                      // mode batch: confirmer le choix
        begin
            initBatchLog;                            // init log
            if not ShowWarning(confbatch.Text) then
            begin
                AddToLog('mode batch annulΘ');
                abort := 'o';
                exit;
            end;
        end;
    end;
// c'est parti
    filmok := False;
    if BatchMode = 0 then
        MrCinemaNorm
    else
        MrCinemaBatch;
end.